VB 2010 Tone Generator library for buttkicker support?

RaceRay · Oct 7, 2013

Hey guys,

is someone here with experience in sound generating via VB?
If we find some working sample code it should be easy to get buttkicker support.

i am helpful for any recommend resource.

Cheers, René

RacingMat · Oct 7, 2013

I'm willing to help!!
- Is it VB or VB.net?

Here is the beginning of a specification list:
- in real time,
- converts telemetry data into a tone
- volume control
- frequency control
- the code should generate "wave sound" and not play ".wav" files
- to external sound speakers

For example, simple "Beep" function do not fit: it has frequency control but doesn't have control volume and uses only internal speakers
;-)

RaceRay · Oct 7, 2013

Hi Mat,

i had hope that you are able to help
dustin already found out that beep is not working, not possible to use peep more than one concurrent at same time...it sucks
So i see that you already paid some attention to it.

We are talking about Visual Basic 2010.

RaceRay · Oct 7, 2013

- we basicly need a app with 5 hor scroll bars on it
- each one turns up the volume of its note
- and each one can have a starting frequency and a ending frequency

yobuddy · Oct 7, 2013

VB.net would be the preferred language.

-theory
The way I see it, is when the app is started, any tones that are need will startup with a zero for volume, and then they get altered on the fly. But I’m sure there are other ways.

-my ideas
I see an app that had 5 horizontal sliders representing the volume of each ‘tone’.
Then each slider has a start and stop frequency so it scales with the volume.

For RPM,
Start frequency of 50
End frequency of 150
As the volume get louder the frequency also increases causing that rev feeling.

For Bumps,
I sample the heave at 10ms and compare the old with the new value, if the value is over a limit value a bump has occurred!
Start frequency of 250
End frequency of 100
As the volume get louder the frequency decreases causing the small bumps to sound like pebbles bouncing off the car, but bug bumps a deeper thud!

-help?
I just need a way to generate a stable tone that does not flicker every time I change the frequency or volume.
Can someone make a simple app that selects a sound card and plays 5 tones with sliders?
I could take it from there I think.
yobuddy

Historiker · Oct 7, 2013

Wow, thanks guys for working on this!

I have been trying to come up with an alternative to just connecting my bass shakers to the same stereo outputs as my speakers. The obvious issue with that is all bass sounds are reproduced regardless of the source (so no music playing while I drive my big rig, lol).

Not sure if this helps at all but I did find a way to split a sound source (in this case the game) to output to two different sound devices. I was going to create a post about this later today and I think I still will for those needing to do so.

I used VB-Audio Cable (virtual device driver) that can take up to two inputs, split them to several outputs if you have the right software.

http://vb-audio.pagesperso-orange.fr/Cable/index.htm

The right software is called Voicemeeter (also by VB-Audio) which takes the input and splits it between two different outputs (physical devices). So now I can adjust each output individually so my speakers have just enough bass to sound good and my other sound card can output only to my bass shakers and is adjustable.

http://vb-audio.pagesperso-orange.fr/Voicemeeter/index.htm

Again, I do not know if this information helps at all with this discussion but I thought I would share.

Again, keep up the great work!

EDIT: Forgot to mention that the software is Donationware. If this works for me, even in the short term, I plan on contributing.

RacingMat · Oct 7, 2013

Hello!

Some data : the frequency range of buttkickers(r) is 5Hz to 200 Hz

May I ask why 5 "channels"?
is it 1 central for engine ? and 4 for 4 wheels?

I have not understood everything in the approach :
- for the engine:
The vibration frequency is given by the telemetry: it's the round per minute RPM!

The vibration amplitude (vibration force) should be stronger for low rpm and weaker for high rpm.
As the vibration amplitude is driven by the volume, the volume has to vary opppositely to frequence, no?

- for bumps:
I would suggest that road bumps would be acquired like this: the variations around the mean value are the signal to be transducted by buttkicker.

In both cases, the cuts (start or end frequency) would distort the reality...

PS: I really love posting images on this forum

Historiker · Oct 7, 2013

I realize that I have no experience with programming (remember I recently did my first "Hello World"?

) but I have been searching for help on this issue.

A very old post (2005) has a code created by a user in the VB Forums which generates a wave file from an input but the author also said that "You can have it make a wave file, and play the wave file, or if you use DirectSound, you can play directly without saving to wav...[to a device]"

Does this help at all or should I just go bugger off now? lol

I really want this project to work.

EDIT: Forgot to include original references:

Found first mention on post #7 here:

http://www.vbforums.com/showthread....y-Generation-HOW&highlight=VB+Tone+Generation

Code and discussion found here:

http://www.vbforums.com/showthread.php?356482-create-wav-file&highlight=frequency

Code:

    Option Explicit
 
    Private Type tWAVEFORMATEX
        wFormatTag As Integer
        nChannels As Integer
        nSamplesPerSec As Long
        nAvgBytesPerSec As Long
        nBlockAlign As Integer
        wBitsPerSample As Integer
        cbSize As Integer
        ExtraData(1 To 32) As Byte ' makes the structure 50 bytes long
    End Type
 
    Private Type FileHeader
        lRiff As Long
        lFileSize As Long
        lWave As Long
        lFormat As Long
        lFormatLength As Long
    End Type
 
    Private Type WaveFormat
        wFormatTag As Integer
        nChannels As Integer
        nSamplesPerSec As Long
        nAvgBytesPerSec As Long
        nBlockAlign As Integer
        wBitsPerSample As Integer
    End Type
 
    Private Type ChunkHeader
        lType As Long
        lLen As Long
    End Type
 
    Private Sub Form_Load()
        Dim Buff(0 To 44100) As Integer
   
        GenerateTone 440, Buff, 1
   
        SaveWaveFile "C:\test_Wave.wav", Buff
    End Sub
 
    Private Sub GenerateTone(ByVal Frequency As Single, IntBuff() As Integer, Optional Amplitude As Single = 1, Optional SamplesPerSec As Long = 44100, Optional Startpos As Long = 0, Optional Length As Long = -1)
        Dim K As Long, V1 As Double
        Const PI As Double = 3.14159265358979
 
        V1 = SamplesPerSec / (PI * 2 * Frequency)
   
        If Length = -1 Then Length = UBound(IntBuff) - Startpos
   
        For K = Startpos To Startpos + Length
            IntBuff(K) = CInt(Fix(Sin(K / V1) * (32766.5 * Amplitude)))
        Next K
    End Sub
 
    Private Sub SaveWaveFile(ByVal WaveFileName As String, ByRef Buffer() As Integer, Optional SamplesPerSec As Long = 44100)
        Dim WF As tWAVEFORMATEX
   
        WF.wFormatTag = 1 'WAVE_FORMAT_PCM
        WF.nChannels = 1
        WF.wBitsPerSample = 16
        WF.nSamplesPerSec = SamplesPerSec
   
        WF.nBlockAlign = (WF.wBitsPerSample * WF.nChannels) \ 8
        WF.nAvgBytesPerSec = WF.nSamplesPerSec * WF.nBlockAlign
   
        Open WaveFileName For Binary Access Write Lock Write As #1
            WaveWriteHeader 1, WF
            Put #1, , Buffer
            WaveWriteHeaderEnd 1
        Close #1
    End Sub
 
    Private Sub WaveWriteHeader(ByVal OutFileNum As Integer, WaveFmt As tWAVEFORMATEX)
        Dim header As FileHeader
        Dim HdrFormat As WaveFormat
        Dim chunk As ChunkHeader
   
        With header
            .lRiff = &H46464952 ' "RIFF"
            .lFileSize = 0
            .lWave = &H45564157 ' "WAVE"
            .lFormat = &H20746D66 ' "fmt "
            .lFormatLength = Len(HdrFormat)
        End With
   
        With HdrFormat
            .wFormatTag = WaveFmt.wFormatTag
            .nChannels = WaveFmt.nChannels
            .nSamplesPerSec = WaveFmt.nSamplesPerSec
            .nAvgBytesPerSec = WaveFmt.nAvgBytesPerSec
            .nBlockAlign = WaveFmt.nBlockAlign
            .wBitsPerSample = WaveFmt.wBitsPerSample
        End With
   
        chunk.lType = &H61746164 ' "data"
        chunk.lLen = 0
   
        Put #OutFileNum, 1, header
        Put #OutFileNum, , HdrFormat
        Put #OutFileNum, , chunk
    End Sub
 
    Private Sub WaveWriteHeaderEnd(ByVal OutFileNum As Integer)
        Dim header As FileHeader
        Dim HdrFormat As WaveFormat
        Dim chunk As ChunkHeader
        Dim Lng As Long
   
        Lng = LOF(OutFileNum)
        Put #OutFileNum, 5, Lng
   
        Lng = LOF(OutFileNum) - (Len(header) + Len(HdrFormat) + Len(chunk))
        Put #OutFileNum, Len(header) + Len(HdrFormat) + 5, Lng
    End Sub

RaceRay · Oct 7, 2013

Thanks for the code but it needs a lot of rewriting. VB 2010 is different to the old VB6. Think i found the code we need:
http://www.vb-paradise.de/allgemein...0-eigene-sounds-generieren-riff-wave-streams/

I try to write a sample app now.

RaceRay · Oct 7, 2013

Very cool. It works. Attached you find a compiled exe and the source code to generate a sinus with 100 hz.

Put the following code into a empty form:

Public Class Form1

'Copyright © ~blaze~ 2011
Public Class SoundGenerator
Private strmStream As IO.Stream
Private rwfcsChunkSettings As RiffWaveFmtChunkSettings
Private bwWriter As IO.BinaryWriter
Private lngLengthOffset As Long
Private lngDataLengthOffset As Long
Private intCurrentLength As Integer

Public ReadOnly Property ChunkSettings() As RiffWaveFmtChunkSettings
Get
Return rwfcsChunkSettings
End Get
End Property

Public Sub New(ByVal destination As IO.Stream, ByVal bufferSettings As RiffWaveFmtChunkSettings)
strmStream = destination
rwfcsChunkSettings = bufferSettings
bwWriter = New IO.BinaryWriter(destination)
bwWriter.Write(1179011410I) '"RIFF" schreiben
'Ermitteln der Position, an der die Laenge der gesamten Datei steht
lngLengthOffset = destination.Position
bwWriter.Write(32I) '32 für die aktuelle Datenlänge in Bytes setzen
bwWriter.Write(1163280727I) '"WAVE" schreiben

'fmt -Chunk
bwWriter.Write(544501094I) '"fmt " schreiben
bwWriter.Write(16I) 'restliche Länge des Blocks setzen
bwWriter.Write(bufferSettings.FormatTag)
bwWriter.Write(bufferSettings.NumberChanels)
bwWriter.Write(bufferSettings.SampleRate)
bwWriter.Write(bufferSettings.BytesPerSecond)
bwWriter.Write(bufferSettings.BlockAlign)
bwWriter.Write(bufferSettings.BitsPerSample)

'data-Chunk
bwWriter.Write(1635017060I) '"data" schreiben
'ermitteln der Position, an der die Laenge des Data-Chunks steht
lngDataLengthOffset = destination.Position
bwWriter.Write(0I)
End Sub

Public Sub Append(ByVal elongations() As Byte)
If rwfcsChunkSettings.BitsPerSample = 8S Then
Dim dataPos As Long = strmStream.Position
Dim data(Buffer.ByteLength(elongations) - 1) As Byte
Buffer.BlockCopy(elongations, 0, data, 0, data.Length) 'Inhalt aus Elongations in data kopieren

strmStream.Seek(lngLengthOffset, IO.SeekOrigin.Begin)
bwWriter.Write(intCurrentLength + data.Length + 32I)

strmStream.Seek(lngDataLengthOffset, IO.SeekOrigin.Begin)
bwWriter.Write(intCurrentLength + data.Length)

strmStream.Seek(dataPos, IO.SeekOrigin.Begin)
bwWriter.Write(data)
Else
Throw New FormatException("The current sound generator does not support elongations of the type System.Byte.")
End If
End Sub

Public Sub Append(ByVal elongations() As Short)
If rwfcsChunkSettings.BitsPerSample = 16S Then
Dim dataPos As Long = strmStream.Position
Dim data(Buffer.ByteLength(elongations) - 1) As Byte
Buffer.BlockCopy(elongations, 0, data, 0, data.Length) 'Inhalt aus Elongations in data kopieren

strmStream.Seek(lngLengthOffset, IO.SeekOrigin.Begin)
bwWriter.Write(intCurrentLength + data.Length + 32I)

strmStream.Seek(lngDataLengthOffset, IO.SeekOrigin.Begin)
bwWriter.Write(intCurrentLength + data.Length)

strmStream.Seek(dataPos, IO.SeekOrigin.Begin)
bwWriter.Write(data)
Else
Throw New FormatException("The current sound generator does not support elongations of the type System.Int16.")
End If
End Sub

Public Sub Append(ByVal elongations() As Integer)
If rwfcsChunkSettings.BitsPerSample = 16I Then
Dim dataPos As Long = strmStream.Position
Dim data(Buffer.ByteLength(elongations) - 1) As Byte
Buffer.BlockCopy(elongations, 0, data, 0, data.Length) 'Inhalt aus Elongations in data kopieren

strmStream.Seek(lngLengthOffset, IO.SeekOrigin.Begin)
bwWriter.Write(intCurrentLength + data.Length + 32I)

strmStream.Seek(lngDataLengthOffset, IO.SeekOrigin.Begin)
bwWriter.Write(intCurrentLength + data.Length)

strmStream.Seek(dataPos, IO.SeekOrigin.Begin)
bwWriter.Write(data)
Else
Throw New FormatException("The current sound generator does not support elongations of the type System.Int32.")
End If
End Sub

Public Sub Append(Of T)(ByVal elongations() As T)
Dim tp As Type = GetType(T) 'Typ der Arrayelemente
Dim vtSize As Integer = Runtime.InteropServices.Marshal.SizeOf(tp) 'Groesse eines Wertetyps
Dim attributes() As Runtime.InteropServices.StructLayoutAttribute = DirectCast(tp.GetCustomAttributes(GetType(Runtime.InteropServices.StructLayoutAttribute), False), Runtime.InteropServices.StructLayoutAttribute())
If Not tp.IsValueType AndAlso (attributes.Length <> 1 OrElse attributes(0).Value = Runtime.InteropServices.LayoutKind.Auto) Then
'Layout von T muss klar definiert sein, bzw. T muss ein Wertetyp sein
Throw New ArgumentException("T is not a value type or its System.Runtime.InteropServices.StructLayoutAttribute is not specified in a correct way. System.Runtime.InteropServices.StructLayoutAttribute.Value mustnot be System.Runtime.InteropServices.LayoutKind.Auto.")
Else
If rwfcsChunkSettings.BitsPerSample = vtSize * 8 Then
Dim dataPos As Long = strmStream.Position
Dim data(Buffer.ByteLength(elongations) - 1) As Byte
'Inhalt aus Elongations in data kopieren, Achtung: keine Arraylaenge ueber Int32.MaxValue moeglich, da
'System.Runtime.InteropServices.Marshal.UnsafeAddrOfPinnedArrayElement keine Int64 als Parameter unterstuetzt
For i As Integer = 0I To elongations.Length - 1I
Runtime.InteropServices.Marshal.Copy(Runtime.InteropServices.Marshal.UnsafeAddrOfPinnedArrayElement(elongations, i), data, vtSize * i, vtSize)
Next
'Laengen updaten
strmStream.Seek(lngLengthOffset, IO.SeekOrigin.Begin)
bwWriter.Write(intCurrentLength + data.Length + 32I)

strmStream.Seek(lngDataLengthOffset, IO.SeekOrigin.Begin)
bwWriter.Write(intCurrentLength + data.Length)

'Daten schreiben
strmStream.Seek(dataPos, IO.SeekOrigin.Begin)
bwWriter.Write(data)
Else
Throw New FormatException(String.Format("The current sound generator does not support elongations of the type {0}.", tp.FullName))
End If
End If
End Sub

Public Sub AppendSine(ByVal frequency As Double, ByVal amplitude As SByte, ByVal duration As TimeSpan)
If rwfcsChunkSettings.BitsPerSample = 8I Then
Dim samples() As Byte = DirectCast(Array.CreateInstance(GetType(Byte), CLng(rwfcsChunkSettings.SampleRate / frequency)), Byte())
Dim data() As Byte
Dim count As Double = duration.TotalSeconds * frequency
Dim dataPos As Long
Dim len As Integer

For l As Long = 0L To samples.LongLength - 1L
samples.SetValue(CByte(128 + CSByte(amplitude * Math.Sin(2 * l * Math.PI * frequency / rwfcsChunkSettings.SampleRate))), l)
Next

data = DirectCast(Array.CreateInstance(GetType(Byte), Buffer.ByteLength(samples)), Byte())
Buffer.BlockCopy(samples, 0, data, 0, data.Length)
dataPos = strmStream.Position

len = CInt(data.Length * count)

'Laengen updaten
strmStream.Seek(lngLengthOffset, IO.SeekOrigin.Begin)
bwWriter.Write(intCurrentLength + len + 32I)

strmStream.Seek(lngDataLengthOffset, IO.SeekOrigin.Begin)
bwWriter.Write(intCurrentLength + len)

For l As Long = 1L To CLng(Math.Floor(count))
bwWriter.Write(data)
Next
bwWriter.Write(data, 0, CInt(data.Length * (count Mod 1)))
Else
Throw New FormatException("The current sound generator does not support elongations of the type System.SByte.")
End If
End Sub

Public Sub AppendSine(ByVal frequency As Double, ByVal amplitude As Short, ByVal duration As TimeSpan)
If rwfcsChunkSettings.BitsPerSample = 16I Then
Dim samples() As Short = DirectCast(Array.CreateInstance(GetType(Short), CLng(rwfcsChunkSettings.SampleRate / frequency)), Short())
Dim data() As Byte
Dim count As Double = duration.TotalSeconds * frequency
Dim dataPos As Long
Dim len As Integer

For l As Long = 0L To samples.LongLength - 1L
samples.SetValue(CShort(amplitude * Math.Sin(2 * l * Math.PI * frequency / rwfcsChunkSettings.SampleRate)), l)
Next
data = DirectCast(Array.CreateInstance(GetType(Byte), Buffer.ByteLength(samples)), Byte())
Buffer.BlockCopy(samples, 0, data, 0, data.Length)
dataPos = strmStream.Position

len = CInt(data.Length * count)

'Laengen updaten
strmStream.Seek(lngLengthOffset, IO.SeekOrigin.Begin)
bwWriter.Write(intCurrentLength + len + 32I)

strmStream.Seek(lngDataLengthOffset, IO.SeekOrigin.Begin)
bwWriter.Write(intCurrentLength + len)

For l As Long = 1L To CLng(Math.Floor(count))
bwWriter.Write(data)
Next
bwWriter.Write(data, 0, CInt(data.Length * (count Mod 1)))
Else
Throw New FormatException("The current sound generator does not support elongations of the type System.Int16.")
End If
End Sub

Public Sub AppendSine(ByVal frequency As Double, ByVal amplitude As Integer, ByVal duration As TimeSpan)
If rwfcsChunkSettings.BitsPerSample = 16I Then
Dim samples() As Integer = DirectCast(Array.CreateInstance(GetType(Integer), CLng(rwfcsChunkSettings.SampleRate / frequency)), Integer())
Dim data() As Byte
Dim count As Double = duration.TotalSeconds * frequency
Dim dataPos As Long
Dim len As Integer

For l As Long = 0L To samples.LongLength - 1L
samples.SetValue(CInt(amplitude * Math.Sin(2 * l * Math.PI * frequency / rwfcsChunkSettings.SampleRate)), l)
Next
data = DirectCast(Array.CreateInstance(GetType(Byte), Buffer.ByteLength(samples)), Byte())
Buffer.BlockCopy(samples, 0, data, 0, data.Length)
dataPos = strmStream.Position

len = CInt(data.Length * count)

'Laengen updaten
strmStream.Seek(lngLengthOffset, IO.SeekOrigin.Begin)
bwWriter.Write(intCurrentLength + len + 32I)

strmStream.Seek(lngDataLengthOffset, IO.SeekOrigin.Begin)
bwWriter.Write(intCurrentLength + len)

For l As Long = 1L To CLng(Math.Floor(count))
bwWriter.Write(data)
Next
bwWriter.Write(data, 0, CInt(data.Length * (count Mod 1)))
Else
Throw New FormatException("The current sound generator does not support elongations of the type System.Int32.")
End If
End Sub
End Class

Public Structure RiffWaveFmtChunkSettings
Public FormatTag As Short
Public NumberChanels As Short
Public SampleRate As Integer
Public BitsPerSample As Short

Public ReadOnly Property BlockAlign() As Short
Get
Return NumberChanels * BitsPerSample \ 8S
End Get
End Property

Public ReadOnly Property BytesPerSecond() As Integer
Get
Return SampleRate * NumberChanels * BitsPerSample \ 8I
End Get
End Property

Public Sub New(ByVal formatTag As Short, ByVal numberChanels As Short, ByVal sampleRate As Integer, ByVal bitsPerSample As Short)
Me.FormatTag = formatTag
Me.NumberChanels = numberChanels
Me.SampleRate = sampleRate
Me.BitsPerSample = bitsPerSample
End Sub
End Structure

Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
Dim stream As New IO.MemoryStream
Dim generator As New SoundGenerator(stream, New RiffWaveFmtChunkSettings(1S, 2S, 44100I, 16S))
Dim soundPlayer As New Media.SoundPlayer
generator.AppendSine(100.0, Short.MaxValue, TimeSpan.FromMilliseconds(500.0))
stream.Seek(0, IO.SeekOrigin.Begin)
soundPlayer.Stream = stream
soundPlayer.Play() 'PlaySync, etc.
End Sub
End Class
Click to expand...

RaceRay · Oct 8, 2013

Ton generator with slider like Dustin asked - That should be good for a first starting.

Edit: Fixed source

RacingMat · Oct 10, 2013

Yes, very nice piano, René! I feel like Mozart!

What's your opinion about the Heave - mean value proposal?

What have you in mind?

BTW after a short while, I got an error "System.OverflowException" with Win Seven and vista! :-(
Code:
System.OverflowException:
WindowsApplication1.Form1.SoundGenerator.AppendSine(Double frequency, Int16 amplitude, TimeSpan duration) dans C:\Users\IronMan\Desktop\tonegenerator2\Tonegenerator\Tonegenerator\Form1.vb:ligne 173
  à WindowsApplication1.Form1.TrackBar1_Scroll(Object sender, EventArgs e) dans C:\Users\IronMan\Desktop\tonegenerator2\Tonegenerator\Tonegenerator\Form1.vb:ligne 286

eaorobbie · Oct 11, 2013

OMG this has great potential, mmm with rpm from the dash out, we should be able to drive this output.
Now working back from what RacingMat has stated a sub woofers range is 5-200Hz that would be 200Hz at lowest rpm and increase to 5Hz on the maxium Rpm or I might have that backwards let all take a look.

RacingMat · Oct 11, 2013

I keep trying detailing the awaiting results,
I hope this help

App output:
For each effect, a sound signal is produced.
Two sound output parameters have to be defined by the app:

- sound frequency
- and sound volume.

For the engine effect:

The vibration frequency is given by the telemetry: it's the round per minute RPM!
Sound Freq (Hz) = Rpm / 60
it's in the range of buttkicker

The vibration amplitude (vibration force) should be stronger for low rpm and weaker for high rpm.
As the vibration amplitude is driven by the volume, the sound volume has to vary opppositely to frequence.
Highest volume for lowest RPM...
(Min RPM and max RPM should be defined)

For Road bumps effects:

Frequency: if Heave is sampled at constant rate,
we can store previous Hdata(t-2) and Hdata(t-1),
acquire Hdata(t),
and we can compute BumpFrequency(t) as Hdata(t) - Hcomputed(t)
like this
or smoother with a moving average over 3 periods for example

Volume: like RPM, the sound volume has to vary opppositely to frequence.

RaceRay · Oct 11, 2013

Interesting stuff...have to examine that more! The code i posted is not usable because there was no way to have multiple streams. Also there are cracks when the single tones are played multiple times in a loop so i decided to look for a real software synthesizer which is able to make tons in "realtime".
I found a library which is able to load Soundfonts. This are (midi) patterns which can played with various settings.
Library is called FluidSynth.

A Soundfont is something like a set of pattern from a specific instrument like a e-Bass, drums, synthesizer etc. Unfortunately i did not found a clean sinus wave as a Soundfont (Its able to create such a sounds with several audio tools but i tried several instrument patterns and the result is very good imho, much better than a clean sinus wave.

I wrote a small quick and dirty testapp for the Soundfonts possibilities.
Download here (22mb): http://www.xsimulator.net/download/tonegenerator.zip

Attention: Some sounds, specially the one with deep frequencies are very dangerous for your speaker. So tune them down

Go in the code and look for .sf2. There you can try out different instrument patterns.:
Code:
 ' load soundfont files
        ' Thats a bass guitar
        'Dim path As String = "sounds\BassFing.sf2"
        ' Thats a Piano
        Dim path As String = "sounds\gorts.sf2"
        'Thats a Drum Kit
        'Dim path As String = "sounds\StomperSet.sf2"
        'Thats a synthesizer
        'Dim path As String = "sounds/198_Juno_StringPad.sf2"
        'Dim path As String = ""
As there are real instrument pattern played and not only steril and clean sinus waves its very easy to create realistic engine vibrations:

Try out (gorts soundfont):

Total play time = 5sec

Duration of tone in ms = 48ms - 100ms

freq / tone = 20 (thats the lowest adjustement of the slider)

If we want very clean sounds we only have to create some sinus soundfonts.
Alternatively i think a similar result can be reached with sinus wave samples. I deliver some of them in the download package.

Btw. Every note is played separately. The volume can vary with every tone.

The slider freq / tone plays the different tones which are on a bank most times roughly from 20 - 60 less or more. So its possible that you select a soundfont and there is no ton when u set the slider to 1-35. So u have to try out to find the range of tones on the virtual keyboard bank,

One thing is still missing in the testapp:
Selection of a specific soundcard. Per default the MS audio driver dsound is used (primary one - can only be changed when the FluidSynth dll are recompiled. )
But its possible to write the sound into stream and choose than the audio card we want:

From: http://fluidsynth.sourceforge.net/api/index.html#MIDIPlayer

It is possible to use the synthesizer object without creating an audio driver. This is desirable if the application using FluidSynth manages the audio output itself. The synthesizer has several API functions that can be used to obtain the audio output:

fluid_synth_write_s16() fills two buffers (left and right channel) with samples coded as signed 16 bits (the endian-ness is machine dependent). fluid_synth_write_float() fills a left and right audio buffer with 32 bits floating point samples. For multi channel audio output, the function fluid_synth_nwrite_float() has to be used.
Click to expand...

Some resources:
http://sourceforge.net/apps/trac/fluidsynth/wiki/SoundFont
http://fluidsynthwrapper.codeplex.com/wikipage?title=Samples&referringTitle=Home

Download Soundfonts:
http://soundfonts.homemusician.net/
http://hammersound.net/cgi-bin/soundlink.pl

About Midi Keymapping, notes and frequencies (german)
http://www.sengpielaudio.com/Rechner-notennamen.htm

If someone can deliver better code, please go ahead.

eaorobbie · Oct 11, 2013

Ok here is a basic app that works in rpm for rfactor only as a test app.
Dash output needs to be set to 50ms in Game Manager, not sure how to reduce this yet.

This doesnt include the new information from Raceray, bugger need to revise

RacingMat · Oct 11, 2013

Hey! "Soundfonts": I used it for a tabla player application (coded with Delphiyears ago)! very rich sounds!
yes, it's (quite) easy to play soundfont sounds called by a midi format.
But for our msecond real time needs, it may be tricky calling sounds or applying affect?...

This morning, I continued my searches:
DirectSound is complex
Windows Multimedia API should do the job

Here is a nice (short) explanation about Signal Synthesis

There is a very simple algorithm for generating a single frequency that you can use as the basis for creating polyphonic wave files. (I have made chords this way, and also you can use that same technique to change the timbre of your voices.)

The formula is based on the way sounds are digitized, and consists of an inner and outer loop. The outer loop controls the length of the wave file, and the inner loop synthesizes the wave itself. I have a series of web pages that I developed a few years ago to try to answer the signal synthesis portion of your question. It is incomplete, and contains more theory than maybe you are looking for, so herer are a couple of links and a bit of pseudocode to get you started.

delta = output frequency * 360 / sample rate
theta = 0
volume = (2^data width - 1) - 1
for i = 0 to sample rate - 1
.........data word = sin(theta % 360) * volume
.........write data word to buffer
.........theta = theta + delta increment
.........buffer pointer
next i
http://www.geocities.com/mtb61275/dsp/audiodsp.htm
http://www.geocities.com/mtb61275/dsp/funcgen.htm

The first link is to to main page of the DSP section. The second page is where I discuss signal synthesis.
Click to expand...

And I looked for VB sine wave generator (without wav file) code: here are the results (zip files uploaded).

http://www.planetsourcecode.com/vb/scripts/ShowCode.asp?txtCodeId=63252&lngWId=1
"A Simple Sine Wave Generator (DirectSound)"
__________
http://forums.codeguru.com/showthread.php?409239-Direct-Soundcard-Control
WaveManip.zip
___________
I hope the first example is fine (I haven't VB2010 to test )

RacingMat · Oct 11, 2013

eaorobbie said: ↑

Ok here is a basic app that works in rpm for rfactor only as a test app.
Click to expand...

Great! Great! I'll test tonight!
Thanks

Historiker · Oct 11, 2013

Arg...have to go install a counter top upstate tonight so I cannot play around with it until Sunday.

eaorobbie · Oct 11, 2013

I haven't worked out yet how to send it to a different sound card , so its really just a proof of the concept that it might actually work.
Im sure that there is a free vb10 on the mircosoft site that might work for compiling and editing.

Log in or Sign up

VB 2010 Tone Generator library for buttkicker support?

RaceRay Administrator Staff Member SimAxe Beta Tester

RacingMat Well-Known Member Gold Contributor

RaceRay Administrator Staff Member SimAxe Beta Tester

RaceRay Administrator Staff Member SimAxe Beta Tester

yobuddy Well-Known Member Staff Member Moderator SimAxe Beta Tester SimTools Developer Gold Contributor

Historiker Dramamine Adict Gold Contributor

RacingMat Well-Known Member Gold Contributor

Historiker Dramamine Adict Gold Contributor

RaceRay Administrator Staff Member SimAxe Beta Tester

RaceRay Administrator Staff Member SimAxe Beta Tester

Attached Files:

tonegenerator.zip

RaceRay Administrator Staff Member SimAxe Beta Tester

Attached Files:

Tonegenerator.zip

RacingMat Well-Known Member Gold Contributor

eaorobbie Well-Known Member SimTools Developer Gold Contributor

RacingMat Well-Known Member Gold Contributor

RaceRay Administrator Staff Member SimAxe Beta Tester

eaorobbie Well-Known Member SimTools Developer Gold Contributor

Attached Files:

GameDash - Test Butkicker.zip

RacingMat Well-Known Member Gold Contributor

Attached Files:

Sine_wave_19480411132005.zip

WaveManip.zip

RacingMat Well-Known Member Gold Contributor

Historiker Dramamine Adict Gold Contributor

eaorobbie Well-Known Member SimTools Developer Gold Contributor